Problem with Request Dialog Box

[newbie]

In VB it is possible to change the caption of a dialog box, is it possible with Rebol because I can't see anywhere to do so.

Then would I need to create my own dialog box just to do that ?

[CarlRead]

No, it would seem you can't change the dialog text.

If you look at the source for REQUEST though, you'll see it uses INFORM to display the window, and this is what the source of INFORM looks like...

Code:

>> source inform
inform: func [
   {Display an exclusive focus panel for alerts, dialogs, and requestors.}
   panel [object!]
   /offset where [pair!] "Offset of panel"
   /title ttl [string!] "Dialog window title"
   /timeout time
][
   panel/text: copy any [ttl "Dialog"]
   panel/offset: either offset [where] [system/view/screen-face/size - panel/size / 2]
   panel/feel: system/view/window-feel
   show-popup panel
   either time [if none? wait time [hide-popup/timeout]] [do-events]
]

So, as a workaround, you could try...

Code:

>> title: second fourth second :inform
== "Dialog"
>> insert clear title "New title!"
== ""
>> request "Test"
== false
>> insert clear title "Another title!"
== ""
>> request "Test"
== false

(The "false"s there are just the result of me closing the request window.)

Cludgy, but quicker than writing your own requests! :-)

Not tested it on the other requests though...

Code:

>> ? "request"
Found these words:
  local-request-file native! Creates an OS-specific file requester
  request         function! Requests an answer to a simple question.
  request-color   function! Requests a color value.
  request-date    function! Requests a date.
  request-dir     function! Requests a directory using a popup list.
  request-download function! Request a file download from the net. Show progres...
  request-file    function! Requests a file using a popup list of files and di...
  request-list    function! Requests a selection from a list.
  request-pass    function! Requests a username and password.
  request-text    function! Requests a text string be entered.